Encuestas-Tico-V1 Public

$nomention
$onlyPerms[admin;]

$var[subcmd;$message[1]] $c[👈 NO cambiar]

$c[👇Prefijos👇]
$var[crear-encuesta;c-encuesta] $c[👈 Se puede cambiar]
$var[activar-encuesta;on-encuesta] $c[👈 Se puede cambiar]
$c[👆Prefijos👆]

$if[$var[subcmd]==$var[crear-encuesta]]

$textSplit[$message;\;]

$if[$getTextSplitLength>7]
$description[❌ Uppsss...
Solo puedes colocar hasta 5 opciones]
$color[ff0000]
$stop
$elseif[$getUserVar[EncuestaV1-By-tico.oficial;$botID;$guildID]!={}]
$description[❌ Uppsss...
Ya tenes una encuesta activa]
$color[ff0000]
$stop
$elseif[$getTextSplitLength<3]
$description[❌ Uppsss...
Coloca minímo una opción]
$color[ff0000]
$stop
$endif

$var[jsonact;{
  "t":"$trimSpace[$replaceText[$splitText[1];$message[1];;1]]",
  "d":"$splitText[2]",
  "e":[\],
  "vt":0}]
$var[tico;2]
$eval[$repeatMessage[$sub[$getTextSplitLength;2];
$$c[]jsonParse[$$c[]var[jsonact\]\]
$$c[]jsonArrayAppend[e\;Discord: tico.oficial\]
$$c[]var[encuesta\;$$c[]replaceText[$$c[]jsonStringify\;"Discord: tico.oficial"\;{"d":"$$c[]trimSpace[$$c[]splitText[$$c[]sum[$$c[]var[tico\]\;1\]\]\]","v":0}\;1\]\]
$$c[]var[jsonact\;$$c[]var[encuesta\]\]
$$c[]var[tico\;$$c[]sum[$$c[]var[tico\]\;1\]\]
]]

$setUserVar[EncuestaV1-By-tico.oficial;$var[encuesta];$botID;$guildID]
$description[✅ Encuesta creada correctamente.
Para publicarla use `$commandTrigger$var[activar-encuesta]`]
$color[00ff00]
$elseif[$var[subcmd]==$var[activar-encuesta]]
$var[0;1️⃣]$var[1;2️⃣]$var[2;3️⃣]$var[3;4️⃣]$var[4;5️⃣]$var[5;6️⃣]$var[6;7️⃣]$var[7;8️⃣]$var[8;9️⃣]$var[9;🔟]
$var[var;$getUserVar[EncuestaV1-By-tico.oficial;$botID;$guildID]]
$if[$var[var]=={}]
$description[❌ Uppsss...
Primero crea una encuesta]
$color[ff0000]
$stop
$endif
$jsonParse[$var[var]]
$removeAllComponents
$enableDecimals[yes]
$var[tico;0]
$addContainer[Encuesta;6e00ff]
$if[$json[t]!=]
$addTextDisplay[## 📊 $json[t];Encuesta]
$addSeparator[false;;Encuesta]
$endif
$if[$json[d]!=]
$addTextDisplay[$json[d];Encuesta]
$endif
$addSeparator[false;;Encuesta]
$eval[$repeatMessage[$jsonArrayCount[e];
$$c[]addTextDisplay[$$c[]var[$$c[]var[tico\]\] | $$c[]json[e\;$$c[]var[tico\]\;d\]
**Votos (0):** `(0%)`\;Encuesta\]
$$c[]addSeparator[true\;\;Encuesta\]
$$c[]var[tico\;$$c[]sum[$$c[]var[tico\]\;1\]\]
]]
$addActionRow[Menu;Encuesta]
$addStringSelect[Menu_Encuesta;Votar;0;0;no;Menu]
$var[tico;0]
$eval[$repeatMessage[$jsonArrayCount[e];
$$c[]addStringSelectOption[Votar por la opción $$c[]sum[$$c[]var[tico\]\;1\]\;$$c[]var[tico\]\;\;$$c[]var[$$c[]var[tico\]\]\;\;Menu_Encuesta\]
$$c[]var[tico\;$$c[]sum[$$c[]var[tico\]\;1\]\]
]]
$addStringSelectOption[Finalizar encuesta;finalizar;;⛔;;Menu_Encuesta]
$deletecommand
$elseif[$var[subcmd]==encuesta-info]
$addField[¿Cómo crear una encuesta?:;
**Simple, solo usa el formato:**

`$commandTrigger$var[crear-encuesta] título\;descripción\;opción1\;opción2\;opción3\;...`

**Ejemplo de uso:**
`$commandTrigger$var[crear-encuesta] Equipo favorito\;Selecciona tu equipo de futbol favorito\;Real Madrid\;Barcelona\;AC Milan`

**NOTA:** Si no deseas colocar un titulo o descripción solamente deja ese espacio vacío. **Ejemplo:**

`$commandTrigger$var[crear-encuesta] \;\;Real Madrid\;Barcelona\;AC Milan`

**Puedes colocar hasta 5 opciones**]
$color[6e00ff]
$endif