Sorteos CV2 Public

$nomention
$onlyIf[$checkContains[$customID;sort;list;finish;reroll;end]==true;]

$textSplit[$customID;-]
$jsonParse[$getUserVar[sorteo;$botID;$splitText[2]]]

$if[$splitText[1]==sort]

$if[$checkContains[$json[joinUsers];$authorID]==false]
$jsonSetString[joinUsers;$json[joinUsers]$authorID/]
$else
$jsonSetString[joinUsers;$replaceText[$json[joinUsers];$authorID/;;-1]]
$endif

$textSplit[$json[joinUsers];/]
$var[cant;$sub[$getTextSplitLength;1]]

$textSplit[$customID;-]
$setUserVar[sorteo;$jsonStringify;$botID;$splitText[2]]

$addContainer[sorteo;ffffff;no]
$addTextDisplay[# ¡Nuevo Sorteo!;sorteo]
$addSeparator[true;small;sorteo]
$addTextDisplay[### **Premio: $splitText[3]**;sorteo]
$addSeparator[true;small;sorteo]

$addActionRow[sd;sorteo]
$addButtonCV2[sort-$splitText[2]-$splitText[3];🎉;secondary;no;;sd]
$addButtonCV2[list-$splitText[2];👥 ($var[cant]);secondary;$checkCondition[$var[cant]==0];;sd]
$addButtonCV2[finish-$splitText[2]-$splitText[3];Finalizar.;danger;no;🔚;sd]

$endif

$if[$splitText[1]==list]

$ephemeral

$textSplit[$json[joinUsers];/]

$var[loop;$cropText[$repeatMessage[10;$repeatMessage[10;s]];$sub[$getTextSplitLength;1];]]
$var[n;1]
$var[lista;$eval[$replaceText[$var[loop];s;$$c[]if[$$c[]splitText[$$c[]var[n\]\]!=\]<@$$c[]splitText[$$c[]var[n\]\]>
$$c[]endif$$c[]var[n\;$$c[]sum[$$c[]var[n\]\;1\]\];-1]]]

$addContainer[sorteo;ffffff;no]
$addTextDisplay[# Lista de participantes;sorteo]
$addSeparator[true;small;sorteo]

$allowUserMentions[]
$addTextDisplay[$replaceText[$var[lista]; ;;-1];sorteo]

$endif

$if[$splitText[1]==finish]

$if[$checkUserPerms[$authorID;managechannels]==false]
$ephemeral
$addContainer[err;ff0000;no]
$addTextDisplay[# Error;err]
$addSeparator[true;small;err]
$addTextDisplay[Necesitas el permiso `Gestionar canales` para finalizar el sorteo.;err]
$stop
$endif

$textSplit[$json[joinUsers];/]
$var[total;$sub[$getTextSplitLength;1]]

$if[$var[total]<=1]
$ephemeral
$addContainer[err;ff0000;no]
$addTextDisplay[# Error;err]
$addSeparator[true;small;err]
$addTextDisplay[No hay participantes suficientes en el sorteo.;err]
$stop
$endif

$var[r;$random[1;$var[total]]]
$var[winner;<@$splitText[$var[r]]>]

$addContainer[fin;ffff00;yes]
$addTextDisplay[# Ya tenemos ganador 🎉;fin]
$addSeparator[true;small;fin]

$allowUserMentions[]

$textSplit[$customID;-]

$addTextDisplay[### Ganador:
$var[winner]
### Premio:
**$splitText[3]**;fin]

$addSeparator[true;small;fin]

$addActionRow[row;fin]
$addButtonCV2[reroll-$splitText[2]-$splitText[3];Rerrol.;secondary;no;🎲;row]
$addButtonCV2[end-$splitText[2];Cerrar.;danger;no;🔒;row]

$removeAllComponents

$endif

$if[$splitText[1]==reroll]

$if[$checkUserPerms[$authorID;managechannels]==false]
$ephemeral
$addContainer[err;ff0000;no]
$addTextDisplay[# Error;err]
$addSeparator[true;small;err]
$addTextDisplay[Necesitas el permiso `Gestionar canales` para hacer rerrol.;err]
$stop
$endif

$jsonParse[$getUserVar[sorteo;$botID;$splitText[2]]]

$textSplit[$json[joinUsers];/]

$var[total;$sub[$getTextSplitLength;1]]
$optOff[$var[r;$random[1;$var[total]]]]
$var[winner;<@$splitText[$var[r]]>]

$addContainer[reroll;ffaa00;no]
$addTextDisplay[# Nuevo ganador 🎉;reroll]
$addSeparator[true;small;reroll]

$allowUserMentions[]

$textSplit[$customID;-]

$addTextDisplay[### Ganador:
$var[winner]
### Premio:
**$splitText[3]**;reroll]

$addSeparator[true;small;reroll]

$addActionRow[row;reroll]
$addButtonCV2[reroll-$splitText[2]-$splitText[3];Rerrol.;secondary;no;🎲;row]
$addButtonCV2[end-$splitText[2];Cerrar.;danger;no;🔒;row]

$endif

$if[$splitText[1]==end]

$if[$checkUserPerms[$authorID;managechannels]==false]
$ephemeral
$addContainer[err;ff0000;no]
$addTextDisplay[# Error;err]
$addSeparator[true;small;err]
$addTextDisplay[Necesitas el permiso `Gestionar canales` para cerrar el sorteo.;err]
$stop
$endif

$textSplit[$customID;-]

$setUserVar[sorteo;{};$botID;$splitText[2]]

$addContainer[end;ff0000;no]
$addTextDisplay[# Sorteo cerrado 🔒;end]
$addSeparator[true;small;end]
$addTextDisplay[El sorteo fue finalizado correctamente.;end]

$removeAllComponents

$endif